CatalanNumber—Wolfram Documentation (original) (raw)

• See Also
  • Binomial
• Related Guides
  • Combinatorial Functions
  • Integer Functions
  • Recurrence and Sum Functions
  • Integer Sequences
• Tech Notes
  • Combinatorial Functions
• • See Also
    * Binomial
  • Related Guides
    * Combinatorial Functions
    * Integer Functions
    * Recurrence and Sum Functions
    * Integer Sequences
  • Tech Notes
    * Combinatorial Functions

Details

• CatalanNumber[n] is generically defined as .
• Catalan numbers are integers for integer arguments, and appear in various tree enumeration problems.
• CatalanNumber can be used with Interval and CenteredInterval objects: »

Examples

open all close all

Basic Examples (1)

The first 10 Catalan numbers:

Wolfram Language code: Table[CatalanNumber[n], {n, 10}]

Scope (9)

Evaluate for large arguments:

Wolfram Language code: CatalanNumber[100000]//Short

Evaluate for half-integer arguments:

Wolfram Language code: CatalanNumber[5 / 2]

Evaluate numerically:

Wolfram Language code: CatalanNumber[2.3]

Evaluate for complex arguments:

Wolfram Language code: CatalanNumber[1.2 + I]

Plot the Catalan number as a function of its index:

Wolfram Language code: Plot[CatalanNumber[n], {n, -3, 3}]

Compute sums involving CatalanNumber:

Wolfram Language code: Sum[1 / CatalanNumber[n], {n, 1, Infinity}]

Wolfram Language code: Sum[(1/4^n) CatalanNumber[n], {n, m - 1}]

CatalanNumber threads element-wise over lists:

Wolfram Language code: CatalanNumber[{1, 2, 3, 4}]

CatalanNumber can be used with Interval and CenteredInterval objects:

Wolfram Language code: CatalanNumber[Interval[{0.5, 0.6}]]

Wolfram Language code: CatalanNumber[CenteredInterval[1, 1 / 100]]

TraditionalForm typesetting:

Wolfram Language code: CatalanNumber[n]//TraditionalForm

Applications (3)

Compute the number of different ways to parenthesize an expression:

Wolfram Language code: SetAttributes[f, {Flat, OneIdentity}]

Distribute over lists in CirclePlus:

Wolfram Language code: e : CirclePlus[___, _List, ___] := Distribute[Unevaluated[e], List]

Use the pattern matcher to repeatedly split the list into two parts in all possible ways:

Wolfram Language code: parenthesizedlist = f[a, b, c, d] //. {f[x__] :> ReplaceList[f[x], f[u_, v_] :> CirclePlus[u, v]]}//Flatten

The number of ways to parenthesize the expression a⊕b⊕c⊕d:

Wolfram Language code: Length[parenthesizedlist]

Check:

Wolfram Language code: CatalanNumber[3]

The Catalan numbers CatalanNumber[n] can be characterized as the unique set of numbers such that two Hankel determinants are both equal to one. Verify for the first few cases:

Wolfram Language code: Table[Det[HankelMatrix[CatalanNumber[Range[0, n]], CatalanNumber[Range[n, 2n]]]] == Det[HankelMatrix[CatalanNumber[Range[n + 1]], CatalanNumber[Range[n + 1, 2n + 1]]]] == 1, {n, 9}]

Verify an expression for the Catalan numbers in terms of double factorials:

Wolfram Language code: Assuming[n∈Integers && n >= 0, FullSimplify[CatalanNumber[n] == (2^2n + 1(2n - 1)!!/(2n + 2)!!)]]

Properties & Relations (6)

The generating function for Catalan numbers:

Wolfram Language code: GeneratingFunction[CatalanNumber[n], n, x]

Wolfram Language code: Series[%, {x, 0, 10}]

Wolfram Language code: Table[CatalanNumber[n], {n, 0, 10}]

Catalan numbers can be represented as a difference of binomial coefficients:

Wolfram Language code: CatalanNumber[n] == Binomial[2n, n] - Binomial[2n, n + 1]

Wolfram Language code: Table[%, {n, -6, 6}]

Wolfram Language code: FunctionExpand[%%]//FullSimplify

Catalan numbers can be represented in terms of the generalized Bell polynomial:

Wolfram Language code: Table[BellY[Transpose[{1 / Range[n, 1, -1]!, Range[n]!}]], {n, 10}]

Wolfram Language code: Table[CatalanNumber[n], {n, 10}]

CatalanNumber can be represented as a DifferenceRoot:

Wolfram Language code: DifferenceRootReduce[CatalanNumber[k], k]

FindSequenceFunction can recognize the CatalanNumber sequence:

Wolfram Language code: Table[CatalanNumber[n], {n, 10}]

Wolfram Language code: FindSequenceFunction[%, n]

The exponential generating function for CatalanNumber:

Wolfram Language code: ExponentialGeneratingFunction[CatalanNumber[n], n, x]

Possible Issues (1)

The Catalan number is, by convention, defined using its representation in terms of binomials:

Wolfram Language code: With[{n = -1}, {CatalanNumber[n], Binomial[2n, n] - Binomial[2n, n + 1]}]

This value is different from the limiting value of the analytic function:

Wolfram Language code: FunctionExpand[CatalanNumber[n]]

Wolfram Language code: Limit[%, n -> -1]

Neat Examples (2)

The only odd Catalan numbers are those of the form CatalanNumber[2k-1]:

Wolfram Language code: Table[Mod[CatalanNumber[2^n - 1], 10], {n, 20}]

Determinants of Hankel matrices made out of sums of Catalan numbers:

Wolfram Language code: Table[Det[HankelMatrix[CatalanNumber[Range[0, n]] + CatalanNumber[Range[n + 1]], CatalanNumber[Range[n, 2n]] + CatalanNumber[Range[n + 1, 2n + 1]]]], {n, 0, 9}]

Compare with an expression in terms of the Fibonacci numbers:

Wolfram Language code: Table[Fibonacci[2n + 3], {n, 0, 9}]

Wolfram Research (2007), CatalanNumber, Wolfram Language function, https://reference.wolfram.com/language/ref/CatalanNumber.html (updated 2014).

Text

Wolfram Research (2007), CatalanNumber, Wolfram Language function, https://reference.wolfram.com/language/ref/CatalanNumber.html (updated 2014).

CMS

Wolfram Language. 2007. "CatalanNumber." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2014. https://reference.wolfram.com/language/ref/CatalanNumber.html.

APA

Wolfram Language. (2007). CatalanNumber. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CatalanNumber.html

BibTeX

@misc{reference.wolfram_2026_catalannumber, author="Wolfram Research", title="{CatalanNumber}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/CatalanNumber.html}", note=[Accessed: 16-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_catalannumber, organization={Wolfram Research}, title={CatalanNumber}, year={2014}, url={https://reference.wolfram.com/language/ref/CatalanNumber.html}, note=[Accessed: 16-June-2026]}